Mathematical Modeling of Social Phenomena

Dr. Courtney Brown

Assignment #8

The data for unemployment rates from 1948 to 1968 for white males, white females, and black males are supplied below. The programming below plots white male unemployment rates and white female unemployment rates overtime. The same is done for white male unemployment rates and black male unemployment rates. Take a look at those plots. Print them out and study them closely.

The programming below then plots the first differences for black male unemployment rates. Look at the regression that follows this plot.

The programming below then plots a first-order linear difference equation on top of black male unemploment rates overtime. Take a look. Hmmmm.

Re-group.

The programming below then regresses white female unemployment rates on white male unemployment rates. You will also find the regression for black male unemployment rates on white male unemployment rates. The programming below then plots white female unemployment rates on top of white male unemployment rates, as well as black male unemployment rates on top of white male unemployment rates.

Your assignment is two-fold. First, try to figure out what is being demonstrated by the series of plots and regressions descibed above. Second, clean up the plots near the bottom of the programming below. Make everything look nice as in the earlier plots.

Make some nice tables, and print these out with your plots. Write up a few pages of text that interpret your results, and hand it all in.

NOTE: The concept of this interesting assignment was originally developed by Professor John Sprague.

Below is the SAS code that will do the analysis of the data. Cut and paste everything below this line into your SAS editor.

GOPTIONS lfactor=10 hsize=6 in vsize=6 in horigin=1 in vorigin=2 in ftitle=swissb ftext=swissb htitle=2 htext=1.5;
options nocenter;
**********************************************************;
* CLASS, NOTE THAT IF YOU BEGIN A LINE WITH AN ASTERISK *
* THEN YOU CAN PUT NOTES IN YOUR PROGRAM FILES. THIS IS
* LIKE A COMMENT CARD IN SPSS. HOWEVER, REMEMBER
* TO EVENTUALLY PUT A FINAL SEMICOLON AT THE END OF YOUR COMMENTS.;
***********************************************************;
* NOTE THAT I INDENT SOME STATEMENTS. THIS
* IS JUST FOR NEATNESS.;
***********************************************************;
* COPYRIGHT (c) Courtney Brown 2004, All Rights Reserved;
* Permission granted to use this file and computer code for any nonprofit and
* educational purposes, including classroom instruction.
* No further permission required.
* Please cite source as "From www.courtneybrown.com";
***********************************************************;
DATA SASSIGN8;
INPUT YEAR 1-4 WMALE 6-8 WFEMALE 10-12 BLKMALE 14-17;
CARDS;
1948 3.4 3.8 5.8
1949 5.6 5.7 9.6
1950 4.7 5.3 9.4
1951 2.6 4.2 4.9
1952 2.5 3.3 5.2
1953 2.5 3.1 4.8
1954 4.8 5.6 10.3
1955 3.7 4.3 8.8
1956 3.4 4.2 7.9
1957 3.6 4.3 8.3
1958 6.1 6.2 13.8
1959 4.6 5.3 11.5
1960 4.8 5.3 10.7
1961 5.7 6.5 12.8
1962 4.6 5.5 10.9
1963 4.7 5.8 10.5
1964 4.1 5.5 8.9
1965 3.6 5.0 7.4
1966 2.8 4.3 6.3
1967 2.7 4.6 6.0
1968 2.6 4.3 5.6
;
DATA SASSIGN8;SET;
LBLKMALE=LAG(BLKMALE);
LABEL WMALE=UNEMPLOYMENT RATE FOR WHITE MALES;
LABEL WFEMALE=UNEMPLOYMENT RATE FOR WHITE FEMALES;
LABEL BLKMALE=UNEMPLOYMENT RATE FOR BLACK MALES;
LABEL LBLKMALE=LAGGED UNEMPLOYMENT RATE BLACK MALES;
symbol1 color=black v=NONE f=centb i=join;
symbol2 color=black f=centb v='.' height=2 interpol=R;
symbol3 color=black f=centb v='.' height=2;

PROC GPLOT;
axis1 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 a=90 r=0 f=swissb c=black 'Unemployment');
axis2 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 f=swissb c=black 'Year');
PLOT WMALE*YEAR='M' WFEMALE*YEAR='F'/ overlay
vaxis=axis1 haxis=axis2 vminor=0 hminor=0;
TITLE 'Figure 1: White Male and White Female Unemployment Rates, 1948-68';

PROC GPLOT;
axis1 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 a=90 r=0 f=swissb c=black 'Unemployment');
axis2 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 f=swissb c=black 'Year');
PLOT WMALE*YEAR='M' BLKMALE*YEAR='B'/ overlay
vaxis=axis1 haxis=axis2 vminor=0 hminor=0;
TITLE 'Figure 2: White Male and Black Male Unemployment Rates, 1948-68';

PROC GPLOT;
axis1 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 a=90 r=0 f=swissb c=black 'Unemployment Rates');
axis2 color=black
value=(h=1.5 f=swissb c=black)
label=(h=1.3 f=swissb c=black 'Lagged Unemployment Rates');
PLOT BLKMALE*LBLKMALE=2 /
vaxis=axis1 haxis=axis2 vminor=0 hminor=0;
TITLE1 'Figure 3: First Differences for';
Title2 'Black Male Unemployment Rates, 1948-68';

PROC REG;
MODEL BLKMALE=LBLKMALE;
DATA TRAJECT;
Y1=5.8;
A=0.555148;
B=3.855764;
DO T=1 TO 21;
Y2=(A*Y1)+B;
OUTPUT;
Y1=Y2;
END;
PROC SORT;
BY T;

DATA SASSIGN8; SET SASSIGN8;
T=YEAR-1947;
DATA COMBINE;
MERGE TRAJECT SASSIGN8;
BY T;
PROC PRINT;

**************************************************;
* YOU NEED TO CLEAN UP THE PLOTS BELOW THIS POINT;
* CONVERT THE PROC PLOT TO PROC GPLOT STATEMENTS;
* AND MAKE EVERYTHING LOOK PRETTY.;
**************************************************;
PROC PLOT;
PLOT BLKMALE*YEAR='B' Y2*YEAR='+'/OVERLAY;
PROC REG;
MODEL WFEMALE=WMALE;
PROC REG;
MODEL BLKMALE=WMALE;
PROC PLOT;
PLOT WFEMALE*WMALE='1' BLKMALE*WMALE='2'/OVERLAY;
run;
quit;